Excel Timer für bessere Produktivität

Excel Timer für bessere Produktivität

Viele Workshop Methoden brauchen eine zeitliche Eingrenzung. Dafür ist es sinnvoll Timer einzusetzen. Ein Tool für Windows und Linux habe ich im Artikel Schnelle Ideen in Workshops vorgestellt. In diesem Artikel zeige ich Ihnen, wie Sie einen universellen Timer mit Microsoft Excel selber bauen und wie Sie damit auch noch Ihre eigene Produktivität verbessern können.

Inhalt

Der Workshop-Timer

Mein ursprüngliches Tool basiert auf Lazarus. Lazarus erzeugt aus dem Quellcode eine echte Anwendung für Windows oder andere Plattformen, wie Linux. Damit lässt es sich perfekt im Betriebssystem integrieren.

Im Einsatz in Firmen ist das manchmal problematisch. Nicht immer ist die Begeisterung groß, eine Anwendung zu installieren. Oder es ist die Angst da, dass sich so Viren einschleusen könnten.

Alternativen gibt es mehrere, beispielsweise Web-Seiten mit Timern:

Damit kann man in Workshops schon gut arbeiten. Nicht perfekt ist allerdings, dass dafür mehrere Fenster geöffnet sein müssen. In einem Fenster steht Ihre Arbeitsanweisung, die Aufgabe für das Workshop-Team oder bisherige Workshop-Ergebnisse, die aktuell notwendig und sichtbar sein müssen. Im anderen Fenster läuft der Timer.

Dazu kommt, dass so ein Timer optisch sehr selten zu den Unternehmensfarben passt. Das könnte wirklich besser sein und es lässt sich auch verbessern und zwar mit Microsoft Excel.

Einen Excel Timer selber bauen

Die Grundlage stellt Excel in einer Methode des Application-Objekts bereit. Die Methode heißt OnTime. Die beiden wichtigsten Parameter sind der Aufrufzeitpunkt als Datum (und Uhrzeit) und die aufzurufende Prozedur.

Im Beispiel wird die Prozedur TimerTick nach 15 Sekunden aufgerufen.

Application.OnTime Now + TimeSerial(0,0,15), „TimerTick“

Für einen Timer, der im Sekundentakt aktualisiert werden soll, wird die Prozedur mit einem TimeSerial(0,0,1) oder TimeValue(„00:00:01“) aufgerufen. Damit das kontinuierlich so passiert, ruft sich die Prozedur TimerTick immer wieder selber auf.

Private Sub TimerTick()
  If isBreak = True Then Exit Sub 
  ThisWorkbook.Sheets(SHEET_SETUP).Range("timer_current") = currentTime
  If currentTime = 0 Then
    Call StopTimer
  Else
    Application.OnTime Now + TimeSerial(0, 0, 1), "TimerTick"
    currentTime = currentTime - 1
  End If
End Sub

TimerTick ist auch der richtige Ort, wenn Sie auf besondere Ereignisse reagieren wollen. Ein Feature ist beispielsweise eine beliebige Sprachausgabe zu einem bestimmten Zeitpunkt. Excel stellt dafür den Befehl Speak bereit, der jeden übergebenen Text spricht.

Ich nutze das, um beim Erreichen von Zeitpunkten einen Text sprechen zu lassen.

Das könnte zum Ende des Timer sein: „Die Zeit ist vorbei“.

Oder ein Countdown: „9-8-7-6-5-4-3-2-1-Ende“.

Was Sie jetzt noch brauchen, ist die Kommunikationsschnittstelle mit dem Benutzer. Für den Timer passiert das am besten über Buttons: Start, Pause, Stopp.

Sub StopTimer()
  currentTime = 0
End Sub

Sub PauseTimer()
  isBreak = Not isBreak
  If isBreak = False Then Call TimerTick
End Sub

Sub StartTimer()
  currentTime = ThisWorkbook.Sheets(SHEET_SETUP).Range("duration_work_sec")
  isBreak = False
  Call TimerTick
End Sub

Einstellungen des Timers möglich machen

Wenn man die Timer sinnvoll nutzen will, muss die Einstellung der Zeitdauer einfach möglich sein. Wenn Sie noch weitere Anforderungen an den Timer haben, ist es umso sinnvoller, diese in ein eigenes Tabellenblatt auszulagern. Ich verwende dafür das Tabellenblatt Setup.

Einstellungen des Excel Timers
Einstellungen des Excel Timers über die Zellen Minuten und Sekunden mit anschließender Umrechnung in der Zelle Dauer in Sekunden

Das Tabellenblatt lässt sich auch hervorragend verwenden, um dort die aktuellen Timer-Stände auszugeben.

Ein erster eigener Excel Timer

Damit haben Sie alle Möglichkeiten selber in der Hand, Ihren Timer zu gestalten. Die Makros zum Starten der einzelnen Funktionen lassen sich neben den normalen Schaltflächen, auch an alle Shape-Elemente anbinden.

Bauen Sie einfach die Befehle ein, die Sie wirklich haben möchten.

Für die Anzeige der Timer-Zeit lassen sich ebenfalls viele Excel-Elemente verwenden.

Datenquelle Tabellenblatt Setup

Grundlage für Ihre Anzeige des Timers ist das Tabellenblatt Setup. Die Prozedure TimerTick schreibt den aktuellen Timer-Wert in die Zelle B11 (noch übrige Zeit). In B12 steht die bereits verstrichene Zeit. Die beiden Timer-Werte haben auch einen Zellnamen, über den Sie sie ansprechen können.

  • Timer-Wert der noch übrigen Zeit: timer_current
  • Timer-Wert vom Beginn an: timer_fromstart

Aus den beiden Werten, die jeweils als Sekundenanzahl vorliegen, berechnet Excel alle weiteren. Die können Sie wiederum für Ihre persönliche Timer-Anzeige verknüpfen.

  • Zellen-Namen für Timer Daten
  • Formeln im Tabellenblatt Setup

Beispiel: Verknüpfung mit einer Zelle

Am einfachsten verknüpfen Sie auf Ihrem Arbeitsblatt die Zelle, wo Sie den Timer anzeigen wollen, mit den aktuellen Timer-Werten aus dem Tabellenblatt Setup.

Verknüpfung einer Zelle mit der noch übrigen Zeit
Verknüpfung einer Zelle (hier D11) mit der noch übrigen Zeit über den Zellnamen „timer_fromstart_formatted“

Klicken Sie nach Eingabe des Gleichheitszeichens auf die entsprechende Zelle im Tabellenblatt Setup – fertig.

Beispiel: Verknüpfung mit einem Shape

Auf die gleiche Weise binden Sie auch einen Timer-Wert an jedes beliebige Shape (unter dem Menüpunkt Formen). Nach Anklicken des Shapes (der Form) können Sie eine Formel zuweisen.

Timer-Daten verküpft mit einer Excel Form (Shape-Objekt)
Timer-Daten verküpft mit einer Excel Form (Shape-Objekt)

Beispiel: Kreisdiagramm

Möchten Sie ein klassisches Format, wie eine ablaufende Uhr, nutzen Sie die Diagrammfunktionen von Excel. Markieren Sie die beiden Werte des Timers (aktuell und übrig) und fügen ein Kreisdiagramm ein. Schon haben Sie einen klassischen Timer.

Workshop Timer mit Aufgabenbeschreibung
Beispiel für einen Workshop Timer mit Aufgabenbeschreibung für das Workshop Team aufgebaut aus einem Kreisdiagramm

Beispiel: Balkendiagramm

Mit dem Weg über ein Diagramm lässt sich auch ein Fortschrittsbalken umsetzen. Als Basis eignet sich dafür ein Balkendiagramm mit gestapelten Säulen.

Fortschrittsanzeige über ein Balkendiagramm
Fortschrittsanzeige über ein Balkendiagramm

Bessere Produktivität

Was hat jetzt ein Timer mit einer besseren Produktivität zu tun? Die Aufgaben von heute sind vielschichtiger und komplexer als früher. Sie erfordern, dass wir uns eingehend mit ihnen beschäftigen. Und das ist anstrengend. Bewusstes Nachdenken ist eben doch harte Arbeit.

Das merkt man selber man besten beim Lösen einer Aufgabe bei der man nicht sofort weiterkommt.

Dann wird das Verlangen größer schnell noch einen Kaffee zu holen, noch ein Blick auf Twitter für neuste Tweets zu werfen, kam noch eine wichtige Mail an oder gibt es etwa überlebenswichtige Neuigkeiten im Unternehmens-Sharepoint?

Um trotzdem konzentriert bei der Aufgabe zu bleiben und weiter zu machen, braucht es Willenskraft. Nach Gary Keller in „The One Thing“ ist unsere Willenskraft aber jeden Tag endlich vorhanden. Sie muss immer wieder aufgeladen werden. Ohne Willenskraft fallen wir auf unsere „Standardeinstellungen“ zurück und sind nicht mehr in der Lage, Neues zu entwickeln.

An diesem Punkt kann ein Timer helfen, um Willenskraft einzusparen. Er kann uns für eine festgelegte Zeit zwingen, nämlich bis zum Ablaufen der Timers, uns mit nur dieser einen Aufgabe zu beschäftigen und alle Ablenkungen auf den Zeitraum danach zu verschieben.

Je mehr der Zyklus „Arbeitsphase-Pausenphase-Arbeitsphase-Pausenphase…“ zu einer Gewohnheit übergeht, desto leichter fällt es, an der Arbeitsphase konzentriert dranzubleiben.

Eine Methode, die das in dieser Form umsetzt, ist die Pomodoro-Technik von Francesco Cirillo. In Deutsch ist sie im Buch „Die Pomodoro-Technik in der Praxis“ von Staffan Nöteberg erklärt.

Pomodoro Technik

Die Pomodoro-Technik setzt als zentrale Basis einen Timer ein. Die Aufgaben werden dabei in kleinere Teile zerlegt, die 25 Minuten betragen. Nach jeder Arbeitsphase – möglichst ohne Ablenkungen – gibt es eine Pausenphase von 5 Minuten. Nach dem Sie so vier Aufgaben abgeschlossen haben, gönnen Sie sich eine längere Pause von üblicherweise 15 bis 30 Minuten.

Entscheidend ist dabei für mich nicht der Timer, sondern die Kombination mit den ersten beiden Punkten: Priorität und Fokus.

Sie werden durch die Methode gezwungen über Ihre wichtigsten Aufgaben nachzudenken. Das ist auch die Quintessenz von Stephen Covey (Die 7 Wege zur Effektivität), Brian Tracy (Eat that frog) oder Brendon Buchard (High power habits).

Im Ergebnis resultieren sie für mich alle sehr ähnlich:

  1. Plane deinen Tag voraus und erstelle eine Prioritätenliste deiner Aufgaben
  2. Fokussiere dich immer nur auf ein Thema / eine Aufgabe
  3. Arbeite daran ohne Unterbrechungen und ohne Ablenkungen bis die Aufgabe erledigt ist

Haben Sie Ihre Aufgaben der höchsten Priorität identifiziert und in eine Reihenfolge gebracht, lässt sich beides mit Excel verbinden und unser selbst gebauter Excel Timer kommt ins Spiel.

Pomodoro-Technik mit Excel Timer

Mit Excel verwalten Sie perfekt Ihre Aufgaben und mit dem integrierten Timer arbeiten Sie ohne Ablenkung nur an einer dieser Aufgabe.

Ein Pluspunkt für Excel ist die Retrospektive, die Rückschau. Erfassen Sie Ihre Aufgaben in Excel sehen Sie am Tagesende, Wochenende oder Monatsende was Sie alles geschafft haben.

Pomodoro-Technik in Excel mit Timer
Beispiel für die Pomodoro-Technik in Excel mit Timer

Noch ein Vorteil ist, dass Sie auch Ereignisse miterfassen können. Für die Pomodoro Technik könnte das zum Beispiel die Anzahl der Ablenkungen in einer Arbeitsphase sein. Wie oft klingelte das Telefon? Haben Sie in Ihr Mail-Postfach geschaut? Wie oft haben Sie dem Drang nach einer Tasse Kaffee nachgegeben?

So haben Sie die Chance zu sehen, wann Ablenkungen bei Ihnen am größten sind und können etwas dagegen tun. Das Schönste ist aber das Gefühl, wenn Sie so eine Pomodoro Session geschafft haben und richtig produktiv waren.

Probieren Sie es aus.

Sie finden alle Beispiele zum Excel Timer unter Download.

Download

Excel Beispiel-Arbeitsmappe herunterladen

Die Exceldatei im Download verwendet Makros. Wenn Sie sich dazu Sorgen machen, finden Sie hier weitere Informationen.

Links

Artikel „Schnelle Ideen in Workshops“: https://techpluscode.de/schnelle-ideen-in-workshops/

Artikel „Besprechungszeit visualisieren“: https://techpluscode.de/besprechungszeit-visualisieren/

Erklärung zur OnTime Funktion auf microsoft.com: https://docs.microsoft.com/de-de/office/vba/api/excel.application.ontime?f1url=%3FappId%3DDev11IDEF1%26l%3Dde-DE%26k%3Dk(vbaxl10.chm133184);k(TargetFrameworkMoniker-Office.Version%3Dv16)%26rd%3Dtrue

Literatur

Gary Keller, The one thing, Redline Verlag, 2017, Seite 68ff

Staffan Nöteberg, Die Pomodoro-Technik in der Praxis, dpunkt.verlag, 2009, Download

Quellcode

Hier der vollständige VBA Quellcode:

Option Explicit

'Name des Tabellenblatts, wo die Einstellungen gespeichert sind
Const SHEET_SETUP = "Setup"

Dim currentTime As Long
Dim isBreak As Boolean

'Funktion berechnet aus einem Sekundenwert einen String im Uhrzeitformat
'Stunden:Minuten:Sekunden
Function SecondsToTimeStr(seconds As Long) As String
Dim h As Integer
Dim m As Integer
Dim s As Integer
Dim rest As Long
  
  h = seconds \ 60 * 60
  rest = seconds - h * 60 * 60
  m = rest \ 60
  s = rest - m * 60

  SecondsToTimeStr = Format(h, "00") & ":" & Format(m, "00") & ":" & Format(s, "00")
End Function

Private Sub TimerTick()
Dim r As Long
Dim c As Long
Dim t As String
Dim ts As Integer

  If isBreak = True Then Exit Sub
  
  'aktuellen Timer im Tabellenblatt aktualisieren
  ThisWorkbook.Sheets(SHEET_SETUP).Range("timer_current") = currentTime
  
  'Prüfen ob eine Sprachausgabe zum aktuellen Zeitpunkt erfolgen soll
  If ThisWorkbook.Sheets(SHEET_SETUP).Range("speech_output") = True Then
  
    'Startzelle der Zeitstempel-Tabelle ermitteln
    r = ThisWorkbook.Sheets(SHEET_SETUP).Range("speech_timestamp").Row
    c = ThisWorkbook.Sheets(SHEET_SETUP).Range("speech_timestamp").Column
    
    'Zeitstempel-Tabelle durchsuchen
    Do Until ThisWorkbook.Sheets(SHEET_SETUP).Cells(r, c) = ""
      ts = CInt(ThisWorkbook.Sheets(SHEET_SETUP).Cells(r, c))
      t = ThisWorkbook.Sheets(SHEET_SETUP).Cells(r, c - 1)
      
      'Wenn ein Zeitstempel ausgeführt werden soll, dann...
      If currentTime = ts Then
        If t <> "" Then Application.Speech.Speak t, True 'Sprachausgabe
      End If
      r = r + 1
    Loop
  End If
  
  If currentTime <= 0 Then
    'wenn die Zeit abgelaufen ist
    Call StopTimer
  Else
    'TimerTick erneut aufrufen
    Application.OnTime Now + TimeSerial(0, 0, 1), "TimerTick"
    currentTime = currentTime - 1
  End If
End Sub

'Prozedur zum Stoppen des Timers
Sub StopTimer()
  currentTime = 0
End Sub

'Prozedur zum Pausieren des Timers
Sub PauseTimer()
  isBreak = Not isBreak
  If isBreak = False Then Call TimerTick
End Sub

'Hilfs-Prozedur zum Starten des Timers
Private Sub StartTimer(seconds As Long)
  currentTime = seconds
  ThisWorkbook.Sheets(SHEET_SETUP).Range("timer_start") = currentTime
  isBreak = False
  Call TimerTick
End Sub

'Prozedur zum Starten des Timers und für die Phase Arbeit bei Pomodoro-Technik
Sub StartTimerWork()
  Call StartTimer(ThisWorkbook.Sheets(SHEET_SETUP).Range("duration_work_sec"))
End Sub

'Prozedur zum Stoppen des Timers für die Phase Pause (für Pomodoro-Technik)
Sub StartTimerBreak()
  Call StartTimer(ThisWorkbook.Sheets(SHEET_SETUP).Range("duration_break_sec"))
End Sub

Kommentar verfassen